PDALConfig.cmake.in

@PACKAGE_INIT@

set(PDAL_VERSION_MAJOR @PDAL_VERSION_MAJOR@)
set(PDAL_VERSION_MINOR @PDAL_VERSION_MINOR@)
set(PDAL_VERSION_PATCH @PDAL_VERSION_PATCH@)

set_and_check(PDAL_INCLUDE_DIRS "@PACKAGE_INCLUDE_INSTALL_DIR@")
set_and_check(PDAL_LIBRARY_DIRS "@PACKAGE_LIB_INSTALL_DIR@")

include("${CMAKE_CURRENT_LIST_DIR}/pluginmacros.cmake")
include("${CMAKE_CURRENT_LIST_DIR}/PDALTargets.cmake")

#
# Note: One should be able to just link libpdalcpp.so/dylib/lib.  But
#   I can't find a way to use @PDAL_LIB_NAME@ because it's not
#   an actual library that cmake knows about.  If you can figure this out,
#   a change would be nice.
#
set(PDAL_LIBRARIES @PDAL_LIB_NAME@)

set(PDAL_LIB_TYPE @PDAL_LIB_TYPE@)
set(PDAL_WITH_ZLIB @WITH_ZLIB@)
set(PDAL_WITH_ZSTD @WITH_ZSTD@)
if (${PDAL_LIB_TYPE} STREQUAL "STATIC")
  find_package(CURL REQUIRED)
  find_package(GDAL CONFIG REQUIRED)
  find_package(PROJ 9.0 REQUIRED CONFIG)
  find_package(LibXml2)
  if (PDAL_WITH_ZLIB)
    find_package(ZLIB REQUIRED)
  endif ()
  if (PDAL_WITH_ZSTD)
    find_package(zstd REQUIRED)
  endif ()
endif ()

check_required_components(PDAL)