parallel_programming_course/cmake/onetbb.cmake at 544215b740f8ff98ac7b341603c34c807c86c870 · learning-process/parallel_programming_course · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
include(ExternalProject)

if(WIN32)
  set(ppc_onetbb_TEST_COMMAND
      "${CMAKE_COMMAND}" -E copy_directory
      "${CMAKE_CURRENT_BINARY_DIR}/ppc_onetbb/install/bin"
      "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}")
else()
  set(ppc_onetbb_TEST_COMMAND "")
endif()

ExternalProject_Add(
  ppc_onetbb
  SOURCE_DIR "${CMAKE_SOURCE_DIR}/3rdparty/onetbb"
  PREFIX "${CMAKE_CURRENT_BINARY_DIR}/ppc_onetbb"
  BINARY_DIR "${CMAKE_CURRENT_BINARY_DIR}/ppc_onetbb/build"
  INSTALL_DIR "${CMAKE_CURRENT_BINARY_DIR}/ppc_onetbb/install"
  CMAKE_ARGS -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
             -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
             -DCMAKE_C_COMPILER_LAUNCHER=${CMAKE_C_COMPILER_LAUNCHER}
             -DCMAKE_CXX_COMPILER_LAUNCHER=${CMAKE_CXX_COMPILER_LAUNCHER}
             -DCMAKE_C_FLAGS=-w
             -DCMAKE_CXX_FLAGS=-w
             -DCMAKE_CXX_STANDARD=${CMAKE_CXX_STANDARD}
             -DCMAKE_CXX_STANDARD_REQUIRED=ON
             -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
             -DTBB_TEST=OFF
  BUILD_COMMAND
    "${CMAKE_COMMAND}" --build "${CMAKE_CURRENT_BINARY_DIR}/ppc_onetbb/build"
    --config ${CMAKE_BUILD_TYPE} --parallel
  INSTALL_COMMAND
    "${CMAKE_COMMAND}" --install "${CMAKE_CURRENT_BINARY_DIR}/ppc_onetbb/build"
    --prefix "${CMAKE_CURRENT_BINARY_DIR}/ppc_onetbb/install"
  TEST_COMMAND ${ppc_onetbb_TEST_COMMAND})

install(DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/ppc_onetbb/install/"
        DESTINATION "${CMAKE_INSTALL_PREFIX}")

string(TOLOWER "${CMAKE_BUILD_TYPE}" cmake_build_type_lower)
if(cmake_build_type_lower STREQUAL "debug")
  set(PPC_TBB_LIB_NAME tbb_debug)
else()
  set(PPC_TBB_LIB_NAME tbb)
endif()