build.gradle.kts

plugins {
    id("java")
    id("org.jetbrains.kotlin.jvm") version "2.0.21"
    id("org.jetbrains.intellij.platform") version "2.5.0"
}

group = "com.boksh"
version = providers.gradleProperty("version").getOrElse("1.0.0")

repositories {
    mavenCentral()
    intellijPlatform {
        defaultRepositories()
    }
}

dependencies {
    intellijPlatform {
        intellijIdeaCommunity("2024.3.5")
        plugin("PythonCore", "243.24978.46")
    }
    testImplementation("org.junit.jupiter:junit-jupiter:5.10.2")
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
    // The IntelliJ platform test initializer on the injected test classpath needs JUnit 4 classes
    testRuntimeOnly("junit:junit:4.13.2")
    testImplementation(kotlin("stdlib"))
}

kotlin {
    jvmToolchain(21)
}

intellijPlatform {
    pluginConfiguration {
        ideaVersion {
            sinceBuild = "242"
            // No upper bound: the plugin only uses stable APIs, so keep it compatible with
            // newer IDEs (e.g. PyCharm 2026.1, build 261) instead of capping at the build platform.
            untilBuild = provider { null }
        }
    }
    buildSearchableOptions = false

    publishing {
        token = providers.environmentVariable("IDEA_PYTHON_SDK_PLUGIN_UPLOAD_TOKEN")
    }
}

tasks.test {
    useJUnitPlatform()
}