MessageHandler/build.gradle.kts at main · SyntaxDevTeam/MessageHandler · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
plugins {
    kotlin("jvm") version "2.4.20" apply false
    id("com.gradleup.shadow") version "9.6.1" apply false
    id("org.jetbrains.dokka-javadoc") version "2.2.0" apply false
}

group = "pl.syntaxdevteam"
version = "1.3.0-R0.3-SNAPSHOT"

tasks.wrapper {
    distributionType = Wrapper.DistributionType.BIN
}

allprojects {
    group = rootProject.group
    version = rootProject.version

    repositories {
        mavenCentral()
        maven("https://repo.papermc.io/repository/maven-public/") {
            name = "papermc-repo"
        }
        maven("https://hub.spigotmc.org/nexus/content/repositories/snapshots/") {
            name = "spigotmc-repo"
        }
        maven("https://oss.sonatype.org/content/groups/public/") {
            name = "sonatype"
        }
    }
}

subprojects {
    apply(plugin = "org.jetbrains.kotlin.jvm")
    apply(plugin = "com.gradleup.shadow")
    apply(plugin = "maven-publish")
    apply(plugin = "org.jetbrains.dokka-javadoc")

    tasks.withType<com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar>().configureEach {
        // Transformery Shadow muszą otrzymać wszystkie duplikaty (m.in. *.kotlin_module),
        // zanim scalą je do pojedynczego wpisu w wynikowym JAR-ze.
        duplicatesStrategy = DuplicatesStrategy.INCLUDE
    }

    val javadocOutputDir = layout.buildDirectory.dir("dokka/javadoc")
    extensions.configure<org.jetbrains.dokka.gradle.DokkaExtension> {
        dokkaPublications.named("javadoc") {
            outputDirectory.set(javadocOutputDir)
        }
    }

    val dokkaJavadoc = tasks.named("dokkaGeneratePublicationJavadoc")
    val javadocJar = tasks.register<Jar>("javadocJar") {
        archiveClassifier.set("javadoc")
        dependsOn(dokkaJavadoc)
        from(javadocOutputDir)
    }

    extensions.configure<PublishingExtension> {
        publications.withType<MavenPublication>().configureEach {
            artifact(javadocJar)
        }
    }
}