Add ability to extract .gnu.version_d section data

Author: staticfloat

src/ELF/ELF.jl

@@ -30,6 +30,7 @@ include("ELFSegment.jl")
 include("ELFSymbol.jl")
 include("ELFDynEntry.jl")
 include("ELFDynamicLink.jl")
+include("ELFVersion.jl")
 
 # Holdovers from ObjFileBase that I haven't cleaned up yet
 #include("ELFRelocation.jl")

src/ELF/ELFVersion.jl

@@ -0,0 +1,65 @@
+export ELFVersionData
+
+# Special ELF version data structures
+@io struct ELFVerDef{H <: ELFHandle}
+    vd_version::UInt16
+    vd_flags::UInt16
+    vd_ndx::UInt16
+    vd_cnt::UInt16
+    vd_hash::UInt32
+    vd_aux::UInt32
+    vd_next::UInt32
+end
+
+@io struct ELFVerdAux{H <: ELFHandle}
+    vda_name::UInt32
+    vda_next::UInt32
+end
+
+@io struct ELFVerNeed{H <: ELFHandle}
+    vn_version::UInt16
+    vn_cnt::UInt16
+    vn_file::UInt16
+    vn_aux::UInt32
+    vn_next::UInt32
+end
+
+struct ELFVersionEntry{H <: ELFHandle}
+    ver_def::ELFVerDef{H}
+    names::Vector{String}
+end
+
+function ELFVersionData(oh::H) where {H <: ELFHandle}
+    s = findfirst(Sections(oh), ".gnu.version_d")
+    strtab = StrTab(findfirst(Sections(oh), ".dynstr"))
+
+    # Queue oh up to the beginning of this section
+    seek(oh, section_offset(s))
+
+    # Read out ALL OF THE version definitions
+    version_defs = ELFVersionEntry[]
+    while true
+        vd_pos = position(oh)
+        vd = unpack(oh, ELFVerDef{H})
+
+        # Find aux names and resolve immediately to strings
+        auxes = String[]
+        aux_offset = 0
+        for aux_idx in 1:vd.vd_cnt
+            seek(oh, vd_pos + vd.vd_aux + aux_offset)
+            aux = unpack(oh, ELFVerdAux{H})
+            name = strtab_lookup(strtab, aux.vda_name)
+            push!(auxes, name)  
+            aux_offset += aux.vda_next
+        end
+
+        push!(version_defs, ELFVersionEntry(vd, auxes))
+
+        if vd.vd_next == 0
+            break
+        end
+        seek(oh, vd_pos + vd.vd_next)
+    end
+    
+    return version_defs
+end

test/linux64/libstdc++.so.6

@@ -162,3 +162,18 @@ end
 # Run COFF tests
 test_libfoo_and_fooifier("./win32/fooifier.exe", "./win32/libfoo.dll")
 test_libfoo_and_fooifier("./win64/fooifier.exe", "./win64/libfoo.dll")
+
+
+# Ensure that ELF version stuff works
+@testset "ELF Version Info Parsing" begin
+    libstdcxx_path = "./linux64/libstdc++.so.6"
+
+    # Extract all pieces of `.gnu.version_d` from libstdc++.so, find the `GLIBCXX_*`
+    # symbols, and use the maximum version of that to find the GLIBCXX ABI version number
+    version_symbols = readmeta(libstdcxx_path) do oh
+        unique(vcat((x -> x.names).(ObjectFile.ELF.ELFVersionData(oh))...))
+    end
+    version_symbols = filter(x -> startswith(x, "GLIBCXX_"), version_symbols)
+    max_version = maximum([VersionNumber(split(v, "_")[2]) for v in version_symbols])
+    @test max_version == v"3.4.25"
+end