client/flake.nix at main · DefGuard/client · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
{
  inputs = {
    nixpkgs.url = "nixpkgs";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
    crane.url = "github:ipetkov/crane";

    # let git manage submodules
    self.submodules = true;
    proto = {
      url = "path:src-tauri/proto";
      flake = false;
    };
    defguard-ui = {
      url = "path:src/shared/defguard-ui";
      flake = false;
    };
    boringtun = {
      url = "path:swift/boringtun";
      flake = false;
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    rust-overlay,
    crane,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      # Plain nixpkgs — used for packages and checks.
      pkgs = import nixpkgs {inherit system;};

      # nixpkgs with rust-overlay — only needed for the dev shell, which uses
      # pkgs.rust-bin to get a customised Rust toolchain.
      devPkgs = import nixpkgs {
        inherit system;
        overlays = [rust-overlay.overlays.default];
      };

      craneLib = crane.mkLib pkgs;
    in {
      devShells.default = import ./nix/shell.nix {
        pkgs = devPkgs;
        inherit crane;
      };

      packages.default = pkgs.callPackage ./nix/package.nix {
        inherit pkgs craneLib;
      };

      checks.default = self.packages.${system}.default;

      formatter = pkgs.alejandra;
    })
    // {
      nixosModules.default = import ./nix/nixos-module.nix {mkCraneLib = crane.mkLib;};
    };
}