jmonkeyengine/settings.gradle at master · 8Keep/jmonkeyengine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
/**
 * This is the global settings file used by all subprojects.
 **/
pluginManagement {
    includeBuild 'jme3-nativeimage-plugin'
    repositories {
        gradlePluginPortal()
        mavenCentral()
        google()
    }
}

plugins {
    id 'org.gradle.toolchains.foojay-resolver-convention' version '1.0.0'
}

rootProject.name = 'jmonkeyengine'

def androidExamplesMinCompileSdk = 34
def isAndroidExamplesTaskRequested = {
    gradle.startParameter.taskNames.any { taskName ->
        taskName == 'runAndroidExamples'
            || taskName == ':runAndroidExamples'
            || taskName == 'jme3-android-examples'
            || taskName.startsWith(':jme3-android-examples:')
            || taskName.startsWith('jme3-android-examples:')
    }
}
def isIosExamplesTaskRequested = {
    gradle.startParameter.taskNames.any { taskName ->
        taskName == 'runIosExamples'
            || taskName == ':runIosExamples'
            || taskName == 'jme3-ios-examples'
            || taskName.startsWith(':jme3-ios-examples:')
            || taskName.startsWith('jme3-ios-examples:')
    }
}
def isJmhTaskRequested = {
    gradle.startParameter.taskNames.any { taskName ->
        taskName == 'jmh'
            || taskName == ':jmh'
            || taskName == 'jme3-benchmark'
            || taskName.startsWith(':jme3-benchmark:')
            || taskName.startsWith('jme3-benchmark:')
    }
}

def findAndroidSdk = {
    def sdkDirs = []

    if (gradle.startParameter.projectProperties['android.sdk.path']) {
        sdkDirs << file(gradle.startParameter.projectProperties['android.sdk.path'])
    }

    def localProperties = file('local.properties')
    if (localProperties.isFile()) {
        Properties properties = new Properties()
        localProperties.withInputStream { properties.load(it) }
        if (properties.getProperty('sdk.dir')) {
            sdkDirs << file(properties.getProperty('sdk.dir'))
        }
    }

    if (System.env.ANDROID_HOME) {
        sdkDirs << file(System.env.ANDROID_HOME)
    }
    if (System.env.ANDROID_SDK_ROOT) {
        sdkDirs << file(System.env.ANDROID_SDK_ROOT)
    }
    if (System.env.ANDROID_HOME) {
        sdkDirs << file(System.env.ANDROID_HOME)
    }
    if (System.env.ANDROID_SDK_ROOT) {
        sdkDirs << file(System.env.ANDROID_SDK_ROOT)
    }
    sdkDirs << file("${System.properties['user.home']}/Android/Sdk")
    sdkDirs << file("${System.properties['user.home']}/Library/Android/sdk")
    sdkDirs << file("${System.properties['user.home']}/AppData/Local/Android/Sdk")

    return sdkDirs.unique { it.absolutePath }.collect { sdkDir ->
        def platformDir = new File(sdkDir, 'platforms')
        def compileSdk = platformDir.listFiles()?.collect { platform ->
            def matcher = platform.name =~ /^android-(\d+)$/
            matcher.matches() && new File(platform, 'android.jar').isFile() ? matcher[0][1] as int : null
        }?.findAll { it != null }?.max()

        [dir: sdkDir, compileSdk: compileSdk]
    }.find { sdk ->
        sdk.dir.isDirectory() && sdk.compileSdk != null && sdk.compileSdk >= androidExamplesMinCompileSdk
    }
}

// Core classes, should work on all java platforms
include 'jme3-core'
if (isJmhTaskRequested()) {
    include 'jme3-benchmark'
}
include 'jme3-effects'
include 'jme3-networking'
include 'jme3-plugins'
include 'jme3-plugins-json'
include 'jme3-plugins-json-gson'

include 'jme3-terrain'

// Desktop dependent java classes
include 'jme3-desktop'
include 'jme3-lwjgl'
include 'jme3-lwjgl3'
include 'jme3-saferallocator'

// Other external dependencies
include 'jme3-jbullet'
include 'jme3-niftygui'
include 'jme3-jogg'
include 'jme3-android'
include 'jme3-ios'

// Example projects
include 'jme3-examples'
include 'jme3-awt-dialogs'

if (isAndroidExamplesTaskRequested()) {
    def androidSdk = findAndroidSdk()
    if (androidSdk != null) {
        System.setProperty('android.home', androidSdk.dir.absolutePath)
        gradle.ext.androidExamplesCompileSdk = androidSdk.compileSdk
        include 'jme3-android-examples'
    }
}
if (isIosExamplesTaskRequested()) {
    include 'jme3-ios-examples'
}
include 'jme3-screenshot-tests'
include 'jme3-screenshot-tests:jme3-screenshot-tests-shared'
include 'jme3-screenshot-tests:jme3-screenshot-tests-desktop'
include 'jme3-screenshot-tests:jme3-screenshot-tests-android'
include 'jme3-screenshot-tests:jme3-screenshot-tests-proto-report'